!
! Ferret/PyFerret Script to plot Figure 1
!
! Biastoch, Sein, Durgadoo, Wang, Danilov
! Simulating the Agulhas system in global ocean models – nesting vs. multi-resolution 
! unstructured meshes, Ocean Modelling, doi: 10.1016/J.OCEMOD-D-17-00174
!

go default
ppl conset ,2

cancel region; cancel view; cancel data/all;can mode logo
def vi/y=0.4:1 tt
def vi/y=0:0.6 bb

define symbol print=no
define symbol filename=resolution

IF ($program_name"0|PyFerret>1|*>0") THEN 
   SET TEXT/FONT=arial
ELSE
   if ($print) then set mode metafile ($filename).plt endif
ENDIf

! Resolution of FESOM, interpolated onto INALT01 base model grid
use resolution_aguv_INALT01.nc
! Grid files (base and nest) for INALT01
use ORCA05-KAB109_mesh_mask.nc
use 1_mesh_mask_B8N.nc

define var/units=degrees_E lamt=glamt[d=2]
define var/units=degrees_N phit=gphit[d=2]


let levs = "(-inf)(5,15,1)(15,50,5)(50,100,10)(inf)/nol/pal=balance-rgb_inverse"
set wi/asp=1.1

set vi tt
fill/lev=`levs`/vlim=-75:75:10/hlim=-180:180:20/set/d=1 resolut/1e3,lon,lat
ppl shakey 0
ppl axlabp,1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=2 tmask[k=1],lamt,phit
label 60,50,-1,,0.14 (a) FESOM

set vi bb
fill/lev=`levs`/vlim=-75:75:10/hlim=-180:180:20/set/d=2 max(e1t,e2t)/1e3,lamt,phit
ppl shakey 1,1,,,,,9.5,9.7,1.3,10
ppl axlabp,-1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
fill/lev=`levs`/ov/d=3 max(e1t,e2t)/1e3,glamt,gphit
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=2 tmask[k=1],lamt,phit
shade/ov/nol/pal=grey/vlim=-50:-8/hlim=-70:70/lev=(0,0.1,0.1)/d=3 tmask[k=1],glamt,gphit
go box (-70) (70) (-50) (8) 7
label 60,50,-1,,0.14 (b) NEMO

IF ($print) THEN
IF ($program_name"0|PyFerret>1|*>0") THEN 
   FRAME/FILE=($filename).pdf
ELSE
   CANCEL MODE META
   sp Fprint -o ($filename).ps -l cps -p portrait ($filename).plt
ENDIF
ENDIF