!
! Ferret/PyFerret Script to plot Figure S1
!
! Biastoch, Sein, Durgadoo, Wang, Danilov
! Simulating the Agulhas system in global ocean models – nesting vs. multi-resolution 
! unstructured meshes, Ocean Modelling, doi: 10.1016/J.OCEMOD-D-17-00174
!

go default
cancel data/all; cancel region; cancel view; can mode logo

define symbol print=yes
define symbol filename=snapshot_zoom

! load snapshot files and masks
!
! FESOM, interpolated onto INALT01 base model grid
use vel_55m_snapshot.nc
! INALT01 base model
use INALT01-KJD308_5d_15-jan-2006_spd.nc
use "../1-resolution/ORCA05-KAB109_mesh_mask.nc"
use "../1-resolution/1_mesh_mask_B8N.nc"

define var/units=degrees_E lamt05=glamt[d=3]
define var/units=degrees_N phit05=gphit[d=3]
define var/units=degrees_E lamt01=glamt[d=4]
define var/units=degrees_N phit01=gphit[d=4]


def vi/y=0.4:1 tt
def vi/y=0:0.6 bb

def vi/x=0:0.38 ll
def vi/x=0.31:0.69 mm
def vi/x=0.62:1 rr


let levs = "(0,5,5)(5,30,1)(30,80,2)(80,125,5)(inf)/nol/pal=balance-rgb"
set wi/asp=1.1 1

IF ($program_name"0|PyFerret>1|*>0") THEN 
   SET TEXT/FONT=arial
ELSE
   if ($print) then set mode metafile ($filename).plt endif
ENDIf

set vi tt
fill/lev=`levs`/vlim=-50:-10:5/hlim=-20:60:10/set ignore0(U[d=1])*100
ppl shakey 0
ppl axlabp,1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=3 tmask[k=1],lamt05,phit05
label 60,50,-1,,0.14 (a) FESOM

set vi bb
fill/lev=`levs`/vlim=-50:-10:5/hlim=-20:60:10/set ignore0(spd05[d=2])*100,lamt05,phit05
ppl shakey 1,1,,,,,9.5,9.7,1.3,10
ppl axlabp,-1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
fill/lev=`levs`/ov ignore0(spd01[d=2])*100,lamt01,phit01
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1) tmask[k=1,d=3],lamt05,phit05
shade/ov/nol/pal=grey/lev=(0,0.1,0.1) tmask[k=1,d=4],lamt01,phit01
go box (-70) (70) (-50) (8) 7
label 60,50,-1,,0.14 (b) NEMO


IF ($print) THEN
IF ($program_name"0|PyFerret>1|*>0") THEN 
   FRAME/FILE=($filename).pdf
ELSE
   CANCEL MODE META
   sp Fprint -o ($filename).ps -l cps -p portrait ($filename).plt
ENDIF
ENDIF