!
! Ferret/PyFerret Script to plot Figure 3
!
! Biastoch, Sein, Durgadoo, Wang, Danilov
! Simulating the Agulhas system in global ocean models – nesting vs. multi-resolution 
! unstructured meshes, Ocean Modelling, doi: 10.1016/J.OCEMOD-D-17-00174
!
go default
ppl conset ,2

cancel region; cancel view; cancel data/all;can mode logo
def vi/y=0.55:1 tt
def vi/y=0.275:0.725 mm
def vi/y=0:0.45 bb

ppl color 6 60 60 60

define symbol print=no
define symbol filename=ssh_zoom

! note that SSH variances and means are preprocessed
!
use agu06_SSH_2000_2007_4b_5day_INALT01-var.nc
use INALT01-KJD308_5d_2000-2007_SSH_detrend_cdo_correctedtaxis-var.nc
use "../1-resolution/ORCA05-KAB109_mesh_mask.nc"
use "../1-resolution/1_mesh_mask_B8N.nc"
use aviso_var_ag_2000-2007_global.nc
use 1_INALT01-KJD308_8y_2000-2007_SSH_detrend.nc
use agu06_SSH_2000_2007_4b_10y_INALT01.nc
use aviso_mean_ag_2000-2007.nc

let ssh_std=100*ssh_var^0.5

let/units=degrees_E lamt=glamt[d=3]
let/units=degrees_N phit=gphit[d=3]
let/units=degrees_E lamt01=glamt[d=4]
let/units=degrees_N phit01=gphit[d=4]


let levs = "(0,10,1)(10,30,2)(inf)/nol/pal=balance-rgb"
set wi/asp=1.4 1

IF ($program_name"0|PyFerret>1|*>0") THEN 
   SET TEXT/FONT=arial
ELSE
   if ($print) then set mode metafile ($filename).plt endif
ENDIf

set vi bb
fill/lev=`levs`/vlim=-50:-10:5/hlim=-20:60:10/set aviso_var[d=5,x=-70:70]^0.5
ppl shakey 1,1,,,,,9.1,9.3,1.5,12
ppl axlabp,-1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
go fland 20
contour/ov/nol/lev=20d 100*SSH[d=8,x=-70:70]-40
label 15,-15,-1,,0.14 (c) AVISO

set vi tt
fill/lev=`levs`/vlim=-50:-10:5/hlim=-20:60:10/set ssh_std[d=1],lamt,phit
ppl shakey 0
ppl axlabp,1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=3 tmask[k=1],lamt,phit
contour/ov/nol/lev=20d 100*SOSSHEIG[d=7],lamt,phit
label 15,-15,-1,,0.14 (a) FESOM

set vi mm
fill/lev=`levs`/vlim=-50:-10:5/hlim=-20:60:10/set ssh_std[d=2],lamt,phit
ppl shakey 0
ppl axlabp,0,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
!shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=3 tmask[k=1],lamt,phit
shade/ov/nol/pal=grey/vlim=-50:-8/hlim=-70:70/lev=(0,0.1,0.1)/d=4 tmask[k=1],glamt,gphit
go box (-70) (70) (-50) (8) 7
contour/ov/nol/lev=20d 100*SOSSHEIG[d=6],lamt01,phit01
label 15,-15,-1,,0.14 (b) NEMO


IF ($print) THEN
IF ($program_name"0|PyFerret>1|*>0") THEN 
   FRAME/FILE=($filename).pdf
ELSE
   CANCEL MODE META
   sp Fprint -o ($filename).ps -l cps -p portrait ($filename).plt
ENDIF
ENDIF