!
! Ferret/PyFerret Script to plot Figure 4
!
! Biastoch, Sein, Durgadoo, Wang, Danilov
! Simulating the Agulhas system in global ocean models – nesting vs. multi-resolution 
! unstructured meshes, Ocean Modelling, doi: 10.1016/J.OCEMOD-D-17-00174
!

go default
ppl conset ,2
set mem/size=300

cancel region; cancel view; cancel data/all;can mode logo
def vi/y=0.4:1 tt
def vi/y=0:0.6 bb

ppl color 6 60 60 60

define symbol print=no
define symbol filename=psi

use agu06_sbarotrob_1951_2007_glob_mm_INALT01.nc
use INALT01-KJD308_1m_19480101_20071231_grid_U_psi.nc
use "../1-resolution/ORCA05-KAB109_mesh_mask.nc"
use "../1-resolution/1_mesh_mask_B8N.nc"

define axis/t="01-jan-1948":"31-dec-2007":1/units="months"/edges/cal=noleap tmon
let/units="Sv" psi_inalt=psi[d=2,gt=tmon@asn]

define axis/t="01-jan-1951":"31-dec-2007":1/units="months"/edges/cal=noleap tmon2
let/units="Sv" psi_fesom=psi[d=1,gt=tmon2@asn]

let/units=degrees_E lamt=glamt[d=3]
let/units=degrees_N phit=gphit[d=3]


let levs = "(-inf)(-80,60,10)(60,150,30)(inf)/nol/pal=balance-rgb_inverse"
set wi/asp=1.1 1

IF ($program_name"0|PyFerret>1|*>0") THEN 
   SET TEXT/FONT=arial
ELSE
   if ($print) then set mode metafile ($filename).plt endif
ENDIf

set vi tt
fill/lev=`levs`/vlim=-75:75:10/hlim=-180:180:20/set psi_fesom[t="01-jan-1988":"31-dec-2007"@ave],lamt,phit
ppl shakey 0
ppl axlabp,1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
!contour/lev=(0)/size=0.01/col=6/nol/ov psi_fesom[t="01-jan-1988":"31-dec-2007"@ave],lamt,phit
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=3 tmask[k=1],lamt,phit
label 60,50,-1,,0.14 (a) FESOM

set vi bb
fill/lev=`levs`/vlim=-75:75:10/hlim=-180:180:20/set psi_inalt[t="01-jan-1988":"31-dec-2007"@ave],lamt,phit
ppl shakey 1,1,,,,,9.5,9.7,1.3,10
ppl axlabp,-1,-1     !labx,laby   -1 (btm,left), 1 (top,right), 0 (none)
ppl axset 1,1,1,1    !top,btm,L,R 
ppl fill
!contour/lev=(0)/size=0.01/col=6/nol/ov psi_inalt[t="01-jan-1988":"31-dec-2007"@ave],lamt,phit
shade/ov/nol/pal=grey/vlim=-75:75/hlim=-180:180/lev=(0,0.1,0.1)/d=3 tmask[k=1],lamt,phit
shade/ov/nol/pal=grey/vlim=-50:-8/hlim=-70:70/lev=(0,0.1,0.1)/d=4 tmask[k=1],glamt,gphit
go box (-70) (70) (-50) (8) 7
label 60,50,-1,,0.14 (b) NEMO


IF ($print) THEN
IF ($program_name"0|PyFerret>1|*>0") THEN 
   FRAME/FILE=($filename).pdf
ELSE
   CANCEL MODE META
   sp Fprint -o ($filename).ps -l cps -p portrait ($filename).plt
ENDIF
ENDIF